Articoli con tag basket

Stanco delle classifiche non aggiornate della FIP di Udine ho pensato farmi la classifica da solo su un foglio excel, e siccome fare la classifica a mano era troppo semplice, ho pensato che il mio foglio excel dovesse generare la classifica autonomamente a partire dai risultati.

La realizzazione non è stata semplice, ma alla fine sono riuscito (con l’aiuto di Google) a trovare una soluzione.

Fase 1: Elaborazione dati

In un foglio (chiamato RisultatiUD) ho riportato su una tabella i risultati delle partite come si può vedere dall’immagine:

Esempio tabella risultati

Le colonne sono:

• A: Squadra di casa
• B: Squadra ospite
• PA: Punteggio squadra A
• PB: Punteggio squadra B
• Ris: risultato calcolato con la funzione =SE(C2>D2;”A”;”B”)
• WinA: mette un 1 se vince A, si calcola con la funzione =SE(E2=”A”;1;0)
• WinB: mette un 1 se vince B, si calcola con la funzione =SE(E2=”B”;1;0)
• LosA: mette un 1 se perde A, si calcola con la funzione =SE(E2=”A”;0;1)
• LosB: mette un 1 se perde B, si calcola con la funzione =SE(E2=”B”;0;1)

In questo modo ho preparato i dati per l’elaborazione della classifica, le ultime quattro colonne mi serviranno per calcolare le vittorie/sconfitte casalinghe ed in trasferta.

Fase 2: Generazione classifica

In un secondo foglio (chiamato ClassificaUD) ho generato una classifica non ordinata come si può vedere dall’immagine:

Classifica non ordinata

Le colonne sono:

• Squadra: il nome della squadra deve essere uguale a quello del foglio dei risultati.
• Punti: vengono calcolati moltiplicando per 2 la colonna delle vittorie. Formula: =E21*2
• DIFF P: calcola la differenza canestri sottraendo le somme punti fatti e punti subiti. Formula: =K21-N21
• G: partite giocate calcolate sommando le vittorie totali alle sconfitte totali. Formula: =E21+H21
• V TT: vittorie totali calcolate sommando le vittorie in casa alle vittorie in trasferta. Formula: =F21+G21
• VC: vittorie in casa calcolate con la seguente formula che spiegherò più avanti: =SOMMA.SE(RisultatiUD!A:A;ClassificaUD!A21;RisultatiUD!F:F)
• VT: vittorie in trasferta calcolata come per VC: =SOMMA.SE(RisultatiUD!B:B;ClassificaUD!A21;RisultatiUD!G:G)
• P TT: perse totali calcolate sommando le sconfitte in casa alle sconfitte in trasferta: Formula: =I21+J21
• PC: perse in casa calcolate come per VC: =SOMMA.SE(RisultatiUD!A:A;ClassificaUD!A21;RisultatiUD!H:H)
• PT: perse in trasferta calcolate come per VC: =SOMMA.SE(RisultatiUD!B:B;ClassificaUD!A21;RisultatiUD!I:I)
• PF TT: punti fatti totale, somma punti fatti in casa e in trasferta. Formula: =L21+M21
• PFC: punti fatti in casa calcolati come per VC: =SOMMA.SE(RisultatiUD!A:A;ClassificaUD!A21;RisultatiUD!C:C)
• PFT: punti fatti in trasferta calcolati come per VC: =SOMMA.SE(RisultatiUD!B:B;ClassificaUD!A21;RisultatiUD!D:D)
• PS TT: punti subiti totale, somma punti subiti in casa e in trasferta. Formula: =O21+P21
• PSC: punti subiti in casa calcolati come per VC: =SOMMA.SE(RisultatiUD!A:A;ClassificaUD!A21;RisultatiUD!D:D)
• PST: punti subiti in trasferta calcolati come per VC: =SOMMA.SE(RisultatiUD!B:B;ClassificaUD!A21;RisultatiUD!C:C)

Vediamo ora il significato del SOMMA.SE usato per la colonna VC e per le altre.

=SOMMA.SE(RisultatiUD!A:A;ClassificaUD!A21;RisultatiUD!F:F)

La sintassi di SOMMA.SE è la seguente SOMMA.SE(Intervallo;Criterio;Int_somma), che tradotto in italiano significa che cercherà il Criterio fra le voci dell’Intervallo e sommerà la corrispondete Int_somma.

Nel mio caso il criterio si trova nella casella A21 del foglio ClassificaUD (nell’esempio Buia), verrà cercato su tutta la colonna A del foglio RisultatiUD (quello delle squadre che giocano in casa) ed una volta trovate tutte le righe corrispondenti, verranno sommati i contenuti delle corrispondeti celle della colonna F nel foglio RisultatiUD.

Cerco di essere ancora più chiaro. Perndiamo ad esempio Buia, la formula cercherà tutti i “Buia” nella colonna A delle squadre in casa e per la riga corrispondente sommerà il contenuto della casella WinA, cioè 1 se vince in casa o 0 se perde in casa. Ho così ottenuto la somma delle vittorie casalinghe di Buia.

Con i dovuti accorgimenti la formula va adattata alle altre situazioni per generare la classifica.

Fase 3: Ordinamento automatico

A questo punto la classifica è pronta, va solo ordinata. Si può utilizzare una macro che ordina automaticamente tutti i dati secondo i propri criteri, oppure si può usare un’altra formula per ottenere questo risultato:

Classifica finita

Le colone sono le stesse della precedente tabella, ma le formule sono differenti. Ho utilizzato principalemente due formule: una per ordinare la colonna Squadre in base ai punti fatti e alla differenza canestri, e l’altra per riportare nelle altre colonne i valori di ciascuna squadra nella riga esatta.

La prima forumula lunghissima è la seguente:

=INDICE($A$21:$A$29;CONFRONTA(GRANDE($B$21:$B$29+($C$21:$C$29)/100-RIF.RIGA($B$21:$B$29)/10000;RIF.RIGA(E21)-RIF.RIGA($E$20));$B$21:$B$29+($C$21:$C$29)/100-RIF.RIGA($B$21:$B$29)/10000;0))

Questa è una formula matriciale e va inserita premendo CTRL+SHIFT+INVIO.

Cerchiamo di scomporre la funzione

• RIF.RIGA(E21)-RIF.RIGA($E$20) questa parte scorre l’elenco e assume i valori da 1 a 9 essendo la mia classifica di 9 posizioni
• GRANDE(…) restituisce il valore massimo di una serie, il secondo parametro è dato dal risultato della funzione precedente ed indica quale valore massimo indicare. Se il risultato è 1, la funzione grande userà il massimo valore, se il risultato 2 userà il secondo più grande e così via.
• CONFRONTA(…) questa funzione cerca all’interno di una serie il risultato della funzione GRANDE e ne restituisce la posizione all’interno dell’elenco.
• INDCE(…) restituisce il valore n-esimo all’interno di una serie.

Non ho detto tutto, come si può notare dalla formula ho sommato a ciascun valore il riferimento della riga diviso per 10000, questo è un espediente che ho utilizzato per poter avere una classifica con più di un risultato uguale. Inoltre vengono sommati i valori della differenza canestri divisi per 100 per poter ottenere una classifica ordinata in base a due parametri.

Queste operazioni vengono fatte sia per la funzione GRANDE che per la funzione CONFRONTA.

La seconda formula è più semplice:

=CERCA.VERT(A3;$A$21:$P$29;2;0)

Questa formula cercherà il contenuto di A3, all’interno della tabella compresa fra A21 e P29 e ne riporterà il valore esatto della seconda colonna alla corrispondente riga. Il 2 indica la colonna e lo 0 indica al valore esatto da riportare.

Per ottenere anche l’ordinamento automatico della classifica mi sono documentato su questa guida, potrebbe tornare comodo dargli un’occhiata.

Questo è tutto, man mano che inserirete i risultati la vostra classifica verrà aggiornata automaticamente. Avrei potuto inserire un excel di esempio, ma non sarebbe stato divertente.